if status is-interactive
    # ========= 命令缩写（仅当目标命令存在）=========
    # ls：优先 eza，其次 exa
    if type -q eza
        abbr ls eza
        abbr ll eza -l
        abbr la eza -a
    else if type -q exa
        abbr ls exa
        abbr ll exa -l
        abbr la exa -a
    end

    type -q bat; and abbr cat bat
    type -q bat; and abbr cap bat -p
    type -q fd; and abbr find fd
    type -q rg; and abbr grep rg
    type -q btop; and abbr top btop
    type -q tldr; and abbr help tldr
    type -q chezmoi; and abbr cz chezmoi

    # ========= thefuck：自动命令纠错 =========
    type -q thefuck; and thefuck --alias | source

    # ========= zoxide：智能目录跳转 =========
    # 使用 --cmd=cd：让 cd 也具备 zoxide 的跳转能力（交互式对应 cdi）
    type -q zoxide; and zoxide init --cmd=cd fish | source

    # ========= 编辑器/查看器（优先 vim，否则 vi）=========
    if type -q vim
        set -gx EDITOR vim
        set -gx VISUAL vim
    else if type -q vi
        set -gx EDITOR vi
        set -gx VISUAL vi
    end

    # ========= fastfetch：启动信息显示 =========
    type -q fastfetch; and fastfetch
end